Aminet 34/Aminet 34 (2000)(Schatztruhe)[!][Dec 1999].iso/Aminet/comm/misc/ViperDaemon.lha/ViperDaemon-Install/Install

Text File | 1999-08-22 | 12KB | 387 lines

; *****************************************
; *                                       *
; *  ViperDaemon-Installationsskript      *
; *                                       *
; *  $VER: 0.1 (22.08.99) by J.Reinert    *
; *                                       *
; *****************************************


; *************************************************************************
; Definition der globalen Konstanten
; *************************************************************************

(set #liesmichtext     "Lies_mich.TXT")       ; Schlusswort
(set #aiconname        "ViperDaemonStart")    ; Name Autostart-Icon
(set #aiconsource      "daemon.noinfo")       ; Quellname Autostart-Icon
(set #aicondest        "SYS:WBStartup")       ; Ziel für Autostart-Icon
(set #doksource        "Docs")                ; Anleitungen
(set #developersource  "Entwickler")          ; Entwickler-Infos
(set #progssource      "Programme")           ; Programme

; *************************************************************************
; Definition der deutschen Texte
; *************************************************************************

(set #askprgdirmsg "Bitte wählen Sie die 'ViperTools'-Schublade aus.")

(set #askprgdirhelp
  (cat "Es ist sehr wichtig, dass Sie die Schublade auswählen, in der "
       "sich das konfigurierte Programm 'ViperTools' befindet. "
       "ViperDaemon verwendet die selbe Prefs-Datei wie ViperTools.\n\n"
       "Falls Sie eine ältere Version per Autostart-Icon starten ließen, "
       "wird der Pfad vermutlich schon stimmen"
  )
)

(set #askdeveloper
  (cat "Wenn Sie Applikationen für ViperDaemon programmieren möchten, "
       "können Sie die dafür notwendigen Informationen umkopieren. Für "
       "ARexx- und Blitz-Programmierer sind Beispiele enthalten\n\n"
       "Möchten Sie die Entwicklerinfos installieren?"
  )
)

(set #askdeveloperdirmsg "Wo soll die Entwickler-Schublade angelegt werden?")

(set #askdeveloperdirhelp
  (cat "Die Entwicklerinfos beinhalten Informationen zu ARexx-Port "
       "und Exec-Messageport sowie Beispiele in ARexx, BlitzBASIC und C. "
  )
)

(set #error_dtinstall1
  (cat "\nAnscheinend haben Sie die falsche Schublade ausgewählt. "
       "Starten Sie die Installation daher erneut.\n\n"
       "Falls Sie 'ViperTools' noch nicht installiert haben, sollten Sie "
       "dies jetzt nachholen"
  )
)

(set #error_dtinstall2
  (cat "\nAnscheinend haben Sie das Programm 'ViperTools' noch "
       "nicht konfiguriert (Prefs-Datei fehlt).\n\n"
       "Starten Sie bitte erst ViperTools, setzen Sie die "
       "Programmeinstellungen und speichern Sie diese. Danach "
       "können Sie diese Installation erneut starten."
  )
)

(set #helpwbstartup
  (cat "Da Sie ein Autostart-Icon installiert haben, ist es nicht "
       "notwendig, daß Sie das Programm 'ViperDaemon' in der 'WBStartup' - Schublade "
       "belassen. Entfernen Sie es bitte."
  )
)

(set #askwbstartup
  (cat "Möchten Sie, daß 'ViperDaemon' bei jedem Rechnerstart "
       "automatisch aktiviert wird ? \n\n"
       "Wenn ja, wird im nächsten Schritt ein Projekt-Icon "
       "in den \"WBStartup\"-Ordner Ihrer Boot-Disk kopiert\n\n"
       "Wenn nein, bleibt ein eventuell vorhandenes Start-Icon erhalten."
  )
)

(set #aiconfail1
  (cat "Es existiert keine 'WBStartup'-Schublade auf Ihrer SYS- "
       "Partition. Wenn Sie 'ViperDaemon' bei jedem Rechnerstart "
       "automatisch in Ihren Rechner laden möchten, wird diese unbedingt "
       "benötigt.\n\nSoll eine Schublade erzeugt werden?"
  )
)

(set #aiconfail2
  (cat "Leider existiert keine 'WBStartup'-Schublade auf Ihrer SYS- "
       "Partition. Automatischer Programmstart ist daher leider nicht möglich."
  )
)

(set #askuserstartup
  (cat "Wenn Sie das Programme 'ShowCounter' auch in "
       "einem Shellfenster starten möchten, können Sie jetzt einen "
       "Suchpfad eintragen lassen. Dazu wird Ihre "
       "'User-Startup' verändert.\n\n"
       "Soll die User-Startup geändert werden?"
  )
)

(set #nodaemon
  (cat "Aus irgend einem Grund wurde das Programm \"ViperDaemon\" nicht "
       "umkopiert. Wiederholen Sie bitte den Installationsvorgang"
  )
)

; *************************************************************************
; Beginn der Installation
; *************************************************************************

(complete 0)

(welcome)

; *************************************************************************
; ViperTools-Pfad ermitteln, falls Icon in SYS:WBStart vorhanden ist
; *************************************************************************

(if (exists (tackon #aicondest "ViperDaemonStart.info"))
  (
    (iconinfo (dest (tackon #aicondest "ViperDaemonStart"))
              (getdefaulttool "testdir")
    )
    (set @default-dest (pathonly testdir))
  )
)

; *************************************************************************
; Zielverzeichnis auswählen lassen
; *************************************************************************

(set #destname
  (askdir
    (prompt  #askprgdirmsg)
    (help    #askprgdirhelp)
    (default @default-dest)
  )
)

(if (= #destname "")
  (
    (abort "Fehler bei Auswahl!")
  )
)

(set #icon_toolentry (tackon #destname "ViperDaemon"))
(set #dokdest (tackon #destname "Docs"))

; *************************************************************************
; ViperTools-Installation prüfen
; *************************************************************************

(if (exists (tackon #destname "ViperTools.wizard") (noreq))
  (
    (if (not (exists (tackon #destname "ViperTools.Prefs") (noreq)))
      (abort #error_dtinstall2)
    )
  )
  (
    (abort #error_dtinstall1)
  )
)

(complete 5)

; *************************************************************************
; Icon-Typ auswählen
; *************************************************************************

(set #icontyp
  (askchoice (prompt "Wählen Sie einen Icon-Typ aus")
             (help "")
             (choices "Standard" "MagicWB")
  )
)
(if (= #icontyp 0)
  (
    (set #iconsource #progssource)
  )
  (
    (set #iconsource "MWBIcons")
  )
)
(complete 10)


; *************************************************************************
; Falls vorhanden, alten ViperDaemon beenden
; *************************************************************************

(if (exists "ExitDaemon")
  (
    (run "ExitDaemon")
    (if (exists "RAM:OldDaemon_Removed")
      (
        (message "Ihre aktive Version von ViperDaemon wurde soeben aus dem Speicher entfernt. Nach erfolgreicher Installation müssen Sie \"ViperDaemon\" neu starten.")
        (delete "RAM:OldDaemon_Removed")
      )
    )
  )
  (
    (message "Eine eventuell aktive Version von ViperDaemon müssen Sie zuerst beenden, bevor Sie weitermachen! Benutzen Sie dazu das Programm \"Exchange\" der Workbench.")
  )
)

; *************************************************************************
; Kopieren der Programme
; *************************************************************************

(if (exists #progssource (noreq))
  (
    (copyfiles (prompt "Programme kopieren")
               (source #progssource)
               (dest #destname)
               (help "")
               (pattern "~(#?.info)")
               (confirm "EXPERT")
    )
  )
)
(complete 50)

; *************************************************************************
; Kopieren der Anleitungen
; *************************************************************************

(if (exists #doksource)
  (
    (copyfiles (prompt "Anleitungen kopieren")
               (source #doksource)
               (dest #dokdest)
               (infos)
               (help "")
               (all)
               (confirm "EXPERT")
    )
  )
)
(complete 55)

; *************************************************************************
; Installieren des Autostart-Icons
; *************************************************************************

(if (exists #aiconsource)
  (
   (if (not (exists #aicondest))
    (if (askbool (prompt #aiconfail1) (help "") (default 0) (choices "Ja" "Nein"))
      (makedir #aicondest (infos))
    )
   )
   (if (exists #aicondest)
    (
      (if (exists #icon_toolentry)
        (
          (if ((askbool (prompt #askwbstartup) (help "") (default 0) (choices "Ja" "Nein")))
            (
              (copyfiles (prompt  "Icon kopieren") (source  #aiconsource) (dest    #aicondest) (newname (cat #aiconname ".info")))

; *************************************************************************
; Default-Tool und Tooltypes (Zukunft) eintragen
; *************************************************************************

              (set #newaiconname (tackon #aicondest #aiconname))

              (if (exists (cat #newaiconname ".info"))
                (
                  (Tooltype (dest #newaiconname) (Setdefaulttool #icon_toolentry))
                  (if (exists "SYS:WBStartup/ViperDaemon")
                    (message #helpwbstartup)
                  )
                )
              )
            )
          )
        )
      )
    )
    (
      (message #aiconfail2)
    )
   )
  )
)
(complete 70)

; *************************************************************************
; Entwicklerinformationen kopieren
; *************************************************************************

(if (exists #developersource)
  (
    (if (askbool (prompt #askdeveloper) (help "") (default 0) (choices "Ja" "Nein"))
      (
        (set developerpath (askdir (prompt  #askdeveloperdirmsg)
                                   (help    #askdeveloperdirhelp)
                                   (default @default-dest)
                      )
        )
        (if (<> developerpath "")
          (

            (set developerdir (tackon developerpath "VD-Entwickler"))
            (makedir developerdir (infos))
            (copyfiles (prompt "Entwicklerinfos kopieren")
                       (source #developersource)
                       (dest developerdir)
                       (infos)
                       (all)
                       (help "")
                       (confirm "EXPERT")
            )
          )
        )
      )
    )
  )
)

(complete 80)

; *************************************************************************
; Kopieren der Icons
; *************************************************************************

(working "Icons kopieren...")

(run (cat "IconCopy " ("ARexx/Counter2TCalc.VDaemon") " " (tackon #destname "/ARexx/Counter2TCalc.VDaemon") " UPDATE"))
(run (cat "IconCopy " (tackon #iconsource "ViperDaemon") " " (tackon #destname "ViperDaemon") " UPDATE"))
(run (cat "IconCopy " (tackon #iconsource "ShowCounter") " " (tackon #destname "ShowCounter") " UPDATE"))
(run (cat "IconCopy " (tackon #iconsource "Docs") " " (tackon #destname "Docs") " UPDATE"))
(complete 85)

; *************************************************************************
; Suchpfad in User-Startup einbinden
; *************************************************************************

(if (askbool (prompt #askuserstartup) (help "") (default 0) (choices "Ja" "Nein"))
  (
    (set cmd (cat "Path "#destname" add"))
    (startup "ViperDaemon-Tools"
             (prompt (cat "Zeile '" cmd "'in User-Startup einfügen"))
             (command cmd)
             (help "")
    )
  )
)

(complete 90)

; *************************************************************************
; Falls vorhanden, einen LiesMich-Text anzeigen
; *************************************************************************

(if (exists #liesmichtext)
  (run (cat "sys:utilities/Multiview " #liesmichtext))
)

; *************************************************************************
; Aktuelles Verzeichnis setzen
; *************************************************************************

(if (exists (tackon #destname "ViperDaemon"))
  (
    (set @default-dest #destname)
  )
  (
    (message #nodaemon)
    (set @default-dest "")
  )
)
(complete 100)

; *************************************************************************
; Ende der Installation
; *************************************************************************